Hallo,
gibt es bei GLBasic einen Befehl mit dem man einen Text blinken lassen kann?
THX
Brauchst nur den Text über einen Timer anzeigen. Also vielleicht nur jede Sekunde oder je nachdem wie du es haben willst
Cheers
Und da Du noch nicht viele Posts geschrieben hast Worebu und denke ich noch Anfänger bist...
Kriegst Du von mir nun einen Vorschlag, wie man sowas baut. :D
Ich bau es Dir gleich in einem sog. Type, damit Du gleich die neue Technik kennenlernst.
// --------------------------------- //
// Project: blinkingText
// Start: Friday, April 27, 2012
// IDE Version: 10.202
// SETCURRENTDIR("Media") // go to media files
//Das ist der Type, indem du "gekapselt" deine Daten für den blinkenden Text hast
TYPE TBlinkingText
text$ //beinhaltet den Text, der angezeigt werden soll
timer% //ist der Timer
blinkEach%
mode% = 1 //0 = aus; 1 = an
//Initialisiert die Variablen
FUNCTION Init: text$, blinkEach% = 1000
self.text$ = text$
self.blinkEach = blinkEach
self.timer = GETTIMERALL() + blinkEach
ENDFUNCTION
FUNCTION Draw: x%, y%
IF self.timer < GETTIMERALL()
//ändert den Modus auf an oder aus
SELECT self.mode
CASE 0
self.mode = 1
CASE 1
self.mode = 0
ENDSELECT
self.timer = GETTIMERALL() + self.blinkEach //Nun den Timer wieder hochzählen (Gesamte Programmlaufzeit + die Timerzeit
ENDIF
IF self.mode = 1 THEN PRINT self.text$, x, y
ENDFUNCTION
ENDTYPE
//Nun wird der BlinkText deklariert und initialisiert
LOCAL meinText AS TBlinkingText
meinText.Init("GLBasic for Dummies :-)")
LOCAL meinZweiterText AS TBlinkingText
meinZweiterText.Init("Und nun schneller...", 500)
LOCAL meinDritterText AS TBlinkingText
meinDritterText.Init("Und noooooooch schneller", 250)
//Nun der MainLoop
WHILE TRUE
meinText.Draw(100, 100)
meinZweiterText.Draw(100, 150)
meinDritterText.Draw(100, 200)
SHOWSCREEN
WEND
P.S. benenne deinen Threadtitel doch bitte in "Wie mache ich blinkenden Text?" oder so um. :)
Cool backslider, und alles noch schön kommentiert. Das muß man sogar als Anfänger verstehen. :good:
Cheers
Na das hoffe ich doch! :)
Ist ja auch auf Anfänger ausgelegt, dass sie es verstehen und gleich lernen, Types zu benutzen! :D
Danke, die Idee habe ich gleich mal so "verbaut".
Quote from: backslider on 2012-Apr-27
P.S. benenne deinen Threadtitel doch bitte in "Wie mache ich blinkenden Text?" oder so um. :)
Ich war so frei, macht schon mehr Sinn!
Sollten wir uns nochmal an das Community-Projekt machen?! :D
Ja, dann finden andere das leichter mit der Suche... An sich hätte ich auch Lust, das Projekt weiterzumachen. :)